# Based on aur/chromium-vaapi, with ungoogled-chromium patches, and some extra tweaks by Michael

# Maintainer: Michael Peters <chris.frog@protonmail.com>

# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=ungoogled-chromium-michael
pkgdesc="Michael's custom build of ungoogled-chromium"

pkgver=101.0.4951.54
pkgrel=1

arch=('x86_64')
license=('BSD')

provides=('chromium')
conflicts=('chromium')

options=('debug' '!lto') # Chromium adds its own flags for ThinLTO

depends=('gtk3' 'nss' 'alsa-lib' 'xdg-utils' 'libxss' 'libcups' 'libgcrypt'
         'ttf-liberation' 'systemd' 'dbus' 'libpulse' 'pciutils' 'libva'
         'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('python' 'gn' 'ninja' 'clang' 'lld' 'gperf' 'nodejs' 'pipewire'
             'java-runtime-headless')
optdepends=('pipewire: WebRTC desktop sharing under Wayland'
            'kdialog: support for native dialogs in Plasma'
            'org.freedesktop.secrets: password storage backend on GNOME / Xfce'
            'kwallet: support for storing passwords in KWallet on Plasma')

source=('chromium-src-release.tar.gz'
        'aur-confs.tar.gz'
        'chromium-launcher.tar.gz')
sha256sums=('d377e88d1b998c61e0d4e65a1a3578f1e21869063f21766fccde8eb60b7fcbcb'
            'cb75bd9700a36858b63067fedd1862c79ebc0086a82bf35064b111f3817fee88'
            'ca5a54b9c50c94c4d1496f529ca7970f5d2fc51bc7546746c132cccdc5d89920')

# Possible replacements are listed in build/linux/unbundle/replace_gn_files.py
# Keys are the names in the above script; values are the dependencies in Arch
declare -gA _system_libs=(
  [ffmpeg]=ffmpeg
  [flac]=flac
  [fontconfig]=fontconfig
  [freetype]=freetype2
  [harfbuzz-ng]=harfbuzz
  [icu]=icu
  [libdrm]=
  [libjpeg]=libjpeg
  [libpng]=libpng
  #[libvpx]=libvpx
  [libwebp]=libwebp
  [libxml]=libxml2
  [libxslt]=libxslt
  [opus]=opus
  [re2]=re2 [snappy]=snappy [zlib]=minizip
)
_unwanted_bundled_libs=(
  $(printf "%s\n" ${!_system_libs[@]} | sed 's/^libjpeg$/&_turbo/')
)
depends+=(${_system_libs[@]})

package() {
    cd "$srcdir/chromium-launcher"

    make PREFIX=/usr DESTDIR="$pkgdir" install
    install -Dm644 LICENSE \
        "$pkgdir/usr/share/licenses/chromium/LICENSE.launcher"

    cd "$srcdir/chromium-src"

    install -D out/Release/chrome "$pkgdir/usr/lib/chromium/chromium"
    install -D out/Release/chromedriver "$pkgdir/usr/bin/chromedriver"
    install -Dm4755 out/Release/chrome_sandbox "$pkgdir/usr/lib/chromium/chrome-sandbox"

    install -Dm644 ../aur-confs/chromium-drirc-disable-10bpc-color-configs.conf \
        "$pkgdir/usr/share/drirc.d/10-$pkgname.conf"

    install -Dm644 chrome/installer/linux/common/desktop.template \
        "$pkgdir/usr/share/applications/chromium.desktop"
    install -Dm644 chrome/app/resources/manpage.1.in \
        "$pkgdir/usr/share/man/man1/chromium.1"
    sed -i \
        -e 's/@@MENUNAME@@/Chromium/g' \
        -e 's/@@PACKAGE@@/chromium/g' \
        -e 's/@@USR_BIN_SYMLINK_NAME@@/chromium/g' \
        "$pkgdir/usr/share/applications/chromium.desktop" \
        "$pkgdir/usr/share/man/man1/chromium.1"

    install -Dm644 chrome/installer/linux/common/chromium-browser/chromium-browser.appdata.xml \
        "$pkgdir/usr/share/metainfo/chromium.appdata.xml"
    sed -ni \
        -e 's/chromium-browser\.desktop/chromium.desktop/' \
        -e '/<update_contact>/d' \
        -e '/<p>/N;/<p>\n.*\(We invite\|Chromium supports Vorbis\)/,/<\/p>/d' \
        -e '/^<?xml/,$p' \
        "$pkgdir/usr/share/metainfo/chromium.appdata.xml"

    local toplevel_files=(
        chrome_100_percent.pak
        chrome_200_percent.pak
        chrome_crashpad_handler
        resources.pak
        v8_context_snapshot.bin

        # ANGLE
        libEGL.so
        libGLESv2.so

        # SwiftShader ICD
        libvk_swiftshader.so
        vk_swiftshader_icd.json
    )

    if [[ -z ${_system_libs[icu]+set} ]]; then
        toplevel_files+=(icudtl.dat)
    fi

    cp "${toplevel_files[@]/#/out/Release/}" "$pkgdir/usr/lib/chromium/"
    install -Dm644 -t "$pkgdir/usr/lib/chromium/locales" out/Release/locales/*.pak
    install -Dm755 -t "$pkgdir/usr/lib/chromium/swiftshader" out/Release/swiftshader/*.so

    for size in 24 48 64 128 256; do
        install -Dm644 "chrome/app/theme/chromium/product_logo_$size.png" \
            "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/chromium.png"
    done

    for size in 16 32; do
        install -Dm644 "chrome/app/theme/default_100_percent/chromium/product_logo_$size.png" \
            "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/chromium.png"
    done

    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/chromium/LICENSE"
}